home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Tiger Disk 167
/
Tiger_Disk_167_19xx_Tiger-Crew-Disk_de_Side_B.d64
/
alpha [td]
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
2023-02-26
|
3KB
|
126 lines
1 rem distributed by zypher innovations
2 poke53280,0:poke53281,0:print"[147][158] e r k l a e r u n g (j/n) ?"
3 getxy$:ifxy$=""then3
4 ifxy$="n"then100
5 print"[147]dieses spiel ist ein 'memory'-spiel. du hast auf einer tafel die"
6 print"verdeckten buchstaben des aphabets."
7 print"mit dem joystick in port 2 waehlst du das feld, das du sehen willst."
8 print"wenn du den gesuchten buchstaben gefun- den hast, drueck' den feuerknopf."
9 print"merk' dir die buchstaben, die du siehst - du hast nicht unbegrenzt zeit!"
10 print"zum spielbeginn drueck' s p a c e [146] !"
11 sys58592
100 sd=54272:fori=sdtosd+24:pokei,0:next:pokesd+5,26:pokesd+6,191:poke54296,15
110 sm=1280:cl=54272:q1=1905:q2=1227
120 hs=0:jc=56320
130 cr$=chr$(19):fori=1to23:cr$=cr$+chr$(17):next:poke53281,1
140 fori=1to7
150 printchr$(31)chr$(147)left$(cr$,9)spc(12)"alpha anxiety"
160 forj=1to50:next
170 printchr$(31)chr$(147)left$(cr$,9)spc(12)"alpha anxiety"
180 forj=1to100:nexti
190 dimp%(25),rl%(5,5)
200 gosub1150
210 rf=0:at=0
220 dl=150
230 sc=0:ma=3
240 l1=1:l2=1:lc=1:fl=1:po=sm:fg=0
250 ifrf=1thenlc=25
260 printchr$(147)
270 print""tab(15)"[144][176][192][178][192][178][192][178][192][178][192][174]"
280 fori=1to4:printtab(15)"[221] [146][221] [146][221] [146][221] [146][221] [146][221]":printtab(15)"[171][192][219][192][219][192][219][192][219][192][179]"
290 next:printtab(15)"[221] [146][221] [146][221] [146][221] [146][221] [146][221]"
300 printtab(15)"[173][192][177][192][177][192][177][192][177][192][189]"
310 print"ges.":print"buchst:":print"[176][192][174]":print"[221] [221]":print"[173][192][189]"
320 print"zeit:":print"score:":print""sc:
330 print"high":print"score:"
340 print"";hs
350 ifsc<2499thenpokeq2+cl,6:pokeq2,lc
360 fori=q1+cltoq1+cl+26:pokei,0:next
370 ti$="000000":cs=160
380 gosub530
390 iffg=1then240
400 ifma=0then450
410 pokesd+4,17:pokesd+1,0
420 tl=dl-int(ti/60)
430 printleft$(cr$,11)spc(2)tl"[157] "
440 iftl>0then380
450 ifsc>hsthenhs=sc
460 printnt"[147] game over"
470 print" drueck' > feuer < fuer"
480 print" noch ein spiel"
490 pokesd+1,85:fori=1to400:next:pokesd+1,0:gosub1150
500 a=notpeek(jc)and16:ifa=0then500
510 printchr$(147):fort=1to500:next
520 goto210
530 p=notpeek(jc)and31
540 je=(p=8)
550 js=(p=2)
560 jw=(p=4)
570 jn=(p=1)
580 jf=(p=16)
590 th=po:t1=l1:t2=l2
600 ifjfthengosub740:goto670
610 ifjethenpo=po+2:l1=l1+1:fl=1
620 ifjsthenpo=po+80:l2=l2+1:fl=1
630 ifjwthenpo=po-2:l1=l1-1:fl=1
640 ifjnthenpo=po-80:l2=l2-1:fl=1
660 pokesd+1,50
670 iffg=1then730
680 ifpo<smorpo>sm+376thenpo=th:l1=t1:l2=t2
690 ifpeek(po+1)=32orpeek(po-1)=32thenpo=th:l1=t1:l2=t2
700 poketh+cl,0:poketh,cs:cs=peek(po)
710 pokepo+cl,2:pokepo,rl%(l1,l2)
720 fl=0
730 return
740 ifrl%(l1,l2)=lcthensc=sc+10:goto780
750 ifrf=1then860
760 ifrl%(l1,l2)<lcthen900
770 goto860
780 pokesd+1,100:fort=1to25:next:pokesd+1,0
790 ifrf=1thenpokeq1+26-lc,lc:goto810
800 pokeq1+lc,lc
810 ifrf=1thenlc=lc-1:goto830
820 lc=lc+1
830 ifsc>2500then850
840 iflc<>0thenpokeq2,lc
850 cs=rl%(l1,l2):goto890
860 pokesd+1,20:fort=1to30:next:pokesd+1,0
870 dl=dl-10:ifdl<=0thengoto460
880 return
890 printleft$(cr$,15)spc(2)sc"[157] "
900 ifrf=0then930
910 iflc<>0then1140
920 goto940
930 iflc<>26then1140
940 ifsc>5000then1000
950 at=at+dl-tl
960 ifsc=5000thendl=int(at/20):goto1050
970 iftl<150thendl=40+tl*2:goto1050
980 iftl>300thendl=tl*.5:goto1050
990 dl=tl
1000 ifsc=6000thendl=dl-5
1010 ifsc=7000thendl=dl-5
1020 ifsc=8000thendl=dl-5
1030 ifsc=9000thendl=dl-5
1040 ifsc=10000thendl=dl-5
1050 h=sd+1:l=sd:pokeh,8:pokel,97:gosub1080
1060 pokeh,12:pokel,143:gosub1080:pokeh,14:pokel,24:gosub1080
1070 pokeh,12:pokel,143:pokesd+4,17:fori=1to800:nexti:pokeh,0:pokel,0:goto1110
1080 pokesd+4,17:fori=1to200:next:pokesd+4,16:fori=1to100:next
1090 pokesd+4,17:fori=1to200:next:pokesd+4,16:fori=1to100:next
1100 return
1110 ifsc>1250thenrf=1
1120 gosub1150
1130 fg=1
1140 return
1150 fori=1to25:p%(i)=i:next
1160 fori=1to5
1170 forj=1to5
1180 r=int(rnd(1)*25+1)
1190 ifp%(r)=0then1180
1200 rl%(i,j)=r
1210 p%(r)=0
1220 nextj
1230 nexti
1240 return